Jabučnjak - Prva stranica PDFova

FSDance
Korisnik

08.08.2009 | 11:58

Dakle, imam par stotina pdfova kojima treba izbrisati prvu stranicu i zatim ih opet spremiti (pozeljno pod istim imenom, ali ne nuzno).
Ima li koji pametniji nacin ili nema do visednevnog kliktanja?
Hvala na mozebitnom odgovoru.

Odgovori Citiraj

smayoo
Moderator

08.08.2009 | 12:05

Apple Script?

Odgovori Citiraj

FSDance
Korisnik

08.08.2009 | 12:10

I meni pade na pamet to…
Samo to podrazumijeva visednevno ucenje applescripta

Hvala svejedno.

Odgovori Citiraj

smayoo
Moderator

08.08.2009 | 12:18

Hm, baš sam gledao... Preview nema svoj Apple Script Dictionary, barem kod mene, u mom Script Editoru. Đipi, help...

Inače, možeš nešto iskemijati i Automatorom, s tim što nema akcije "izbriši stranicu", tako da ti je postupak "izgeneriraj svaku stranicu kao poseban PDF" pa onda " spoji sve posebne PDF stranice osim prve u novi PDF" pa onda "izbriši sve posebne PDF stranice".

Meni je za osnovno savladavanje AppleScripta trebalo par sati, ali to, naravno, ovisi o tome koliko si inače vičan programiranju. U svakom slučaju, za Automator ti ne bi trebalo trebati više od par sati.

Odgovori Citiraj

Tomislav
Korisnik

08.08.2009 | 19:11

Daleko od toga da je besplatno, ali elegantno je. Enfocus PitStop, plugin za Acrobat.

Odgovori Citiraj

Djipi
Korisnik

09.08.2009 | 00:02

Hm, baš sam gledao... Preview nema svoj Apple Script Dictionary, barem kod mene, u mom Script Editoru. Đipi, help...

To the rescue!

Preview definitivno nema svoj AS dictionary, ali to ne znači da nema lijeka. Dapače, ovo je dobar primjer za "think different" unutar samog AppleScripta.

Da ne duljim, skripta...

-- PDF Front Page Stripper (using Preview)
-- (08/08/2009) 1.00 release

-- NOTES:
-- turn ON "Enable access for assistive devices" (System Preferences/Universal Access")
-- save this script as Application (File Format)
-- quit Preview BEFORE using this script
-- don't click mouse during execution

on run
  display dialog "Drag multiple PDF files or a single folder containg PDF files onto this icon!"
end run

on open draggeditems
  set sourcefiles to filelistFromSelection(draggeditems)
  -- main loop  
  repeat with thisFile in sourcefiles
    -- convert AppleScript path to POSIX path
    set pdfRef to POSIX path of thisFile
    -- load PDF into Preview using system shell
    do shell script "open /Applications/Preview.app '" & pdfRef & "'"
    -- emulate clicking
    tell application "System Events"
      tell application "Preview" to activate
      tell process "Preview"
        tell menu bar 1
          tell menu bar item "Edit"
            tell menu "Edit"
              -- dirty hack...
              click menu item "Insert Blank Page" -- ...to get pointer to the front page
              click menu item "Delete Selected Page" -- then remove inserted page
              click menu item "Delete Selected Page" -- and remove the front page
            end tell
          end tell
          tell menu bar item "File"
            tell menu "File"
              click menu item "Save"
            end tell
          end tell
        end tell
      end tell
      -- quit Preview
      tell application "Preview" to quit
    end tell
  end repeat
end open

-- returns dragged files OR files at first level of one dragged folder
on filelistFromSelection(theselection)
  set hasfolder to false
  tell application "Finder"
    repeat with thisItem in (theselection as list)
      if (class of item thisItem is folder) or (class of item thisItem is disk) then
        set hasfolder to true
      end if
    end repeat
  end tell
  if ((count item of (theselection as list)) > 1) and hasfolder then
    display dialog "Drag multiple files or a single folder." buttons {"OK"} default button 1
    return ""
  end if
  tell application "Finder"
    if hasfolder then
      set filelist to (every item of folder (item 1 of (theselection as list))) as alias list
    else
      set filelist to (theselection as list)
    end if
  end tell
  return filelist
end filelistFromSelection

Skripta ima 4 "preduvjeta" korištenja. Dokumentirao sam ih na vrhu same skripte, ali ne škodi ponoviti.

Prvo, potrebno je kliknuti na checkbox "Enable asscess for assitive devices" u System Preferences/Universal Access kako bi se AppleScriptu omogućilo emuliranje kliktanja po izbornicima.

Drugo, potrebno je snimiti skriptu kao droplet ("Application" file format, bira se tijekom Save As u Script Editoru), da bi se na nju moglo dovući (drag&drop) datoteke koje će obraditi.

Treće, treba ugasiti Preview PRIJE pokretanja skripte (ako je slučajno dignut) jer će se u protivnom skripta "izgubiti" (nema nikakav error checking).

I zadnje, tijekom izvršavanja skripte NE smije se kliktati mišem jer zbunjuje emulaciju.

Zanemarimo li funkciju filelistFromSelection() koju smo već vidjeli na Jabučnjaku, skripta je zgodna jer je priseljena koristiti shell za otvaranje dokumenta u Previewu s obzirom da ne možemo (čak ni s emulacijom kliktanja po izbornicima) otvoriti datoteku u Previewu izravno iz AppleScripta. Zaobilazni put je taj da prvo dokučimo POSIX path datoteke koju ćemo obraditi (AppleScript radi sa HFS pathom), a potom ga proslijedimo shellu koji će, koristeći naredbu "open" otvoriti Preview.app i učitati proslijeđenu datoteku (odnosno njezin path). Time smo riješili manji problem.

Veći problem je kako ubiti prvu stranicu. Naime, kad otvorimo PDF u Previewu, pogotovo ako PDF ima index (prikazuje se u Sidebaru), nije nam dostupna opcija Edit/Delete Selected Page - jer nije odabrana konkretna stranica. S obzirom da nemamo pametnog načina za "odabrati" stranicu koju želimo, a defaultno se nalazimo na prvoj stranici, koristimo "prljavi trik" - dodamo jednu praznu stranicu (Insert Blank Page - opcija koja nam je uvijek dostupna) i time dobijemo pointer na nju. Sad možemo "kliknuti" (emulirano) na Delete Selected Page i to dvaput - prvi put ubijemo dodanu stranicu, a drugi put "naslovnu".

Ovdje ima kvaka! Preview pamti stranicu na kojoj smo stali (automatski "bookmark" ). Drugim riječima, ako PDF dokument ima 42 stranice, a zadnji put smo ga učitali i quitali Preview dok smo bili na 21. stranici, kad sljedeći put otvorimo isti dokument, nalazit ćemo se tamo gdje smo stali - na 21. stranici. To znači da bi "prljavi trik" mogao napraviti kaos ako korisnik nije siguran da li su svi dokumenti automatski bookmarkirani na prvoj stranici! Očito nema smisla da korisnik sam provjeri jer bi to značilo otvaranje N dokumenata, odlazak na prvu stranicu i izlazak iz Previewa, a ako to već radi, onda može usput i pobrisati naslovnicu pa ne mora ni čitati ovaj post.

Rješenje kvake? U korisnikovom Library/Preferences folderu nalazi se "com.apple.Preview.bookmarks.plist". Ako ga pobrišemo, Preview će "zaboraviti" sve bookmarke i PDF datoteke koje potom učitamo u njega bit će, defaultno, na naslovnici (page 0).

Naravno, ne moramo ga pobrisati, možemo ga i spremiti ili preimenovati pa kasnije vratiti nazad (ako je potrebno pamtiti stare bookmarke).

Ostatak skripte je trivijalan - nakon što smo uklonili naslovnicu, snimimo preinačeni PDF i ugasimo (quit) Preview. Proces se ponavlja za sve datoteke koje smo odvukli na ikonicu skripte.

Nadam se da je dovoljno elegantno. A i besplatno je.

Odgovori Citiraj

FSDance
Korisnik

09.08.2009 | 00:24

Trazim smileya koji bi ti pokazao moju zahvalnost, ali ne nalazim ga.
Stoga nema nego da castim pivom ili cime vec kad se vidimo

Hvala odsrca.

Odgovori Citiraj

Djipi
Korisnik

09.08.2009 | 00:26

Jedan problem manje u svemiru.

Odgovori Citiraj

smayoo
Moderator

09.08.2009 | 09:16

Đipi, majstore. Majstore...

(Riba, možda da preseliš ovaj thread u Programiranje?)

Pitanja znatiželje radi:

Zašto će skripta biti zbunjena ako Preview nije quit-an prije pokretanja?

Aplikaciji "System Events" se, pretpostavljam obraćaš jer preko nje ide emulacija klikanja u bilo čemu. Ili?

Pretpostavljam da sa "tell application xy to activate" postižeš to da njen menu postane aktivan u menu baru i da to zapravo treba čitati kao "tell application System events to tell application xy to activate"? Da? Ne?

Ono što ne kužim čemu služi je "tell process xy" pa onda "tell menu bar 1"?

Pretpostavljam da općenito bilo koja aplikacija može pokrenuti više procesa (kao više prozora ili...?) pa onda treba System Eventsu reći koji točno proces nas zanima? Da? Ali što onda još "menu bar 1"?

Inače "dirty hack" koji si primijenio ja redovito koristim "ručno", kad PDF ima index pa mi nisu dostupni thumbnailovi stranica da selektiram stranicu. Malo mi je glupasto kako nije moguće odabrati da li se u sidebaru gleda bookmarkove ili thumbnailove...

Odgovori Citiraj

Djipi
Korisnik

09.08.2009 | 23:33

Zašto će skripta biti zbunjena ako Preview nije quit-an prije pokretanja?

System Events je bugovit po pitanju referenciranja pa mu se zna dogoditi da po putu "zaboravi" kome se obraća - i tada se pojavi "Connection is invalid", poruka o grešci. Može se pokrpati sa "try" blokom koda, ali kako nisam želio komplicirati implementirajući error checking, alternativa je pobrinuti se da se ne zbuni tako što neće postojati druga aktivna referenca u trenutku obraćanja aplikaciji.

Aplikaciji "System Events" se, pretpostavljam obraćaš jer preko nje ide emulacija klikanja u bilo čemu. Ili?

Tako je. "System Events" je jedan od "agenata" (kako ih Apple zove; u pitanju je background aplikacija), poput "Image Events" i "Database Events". Sva tri proširuju osnovni AppleScript, a "System Events" je najopširniji i zadužen, između ostalog, i za GUI (kao rješenje za kontroliranje onih aplikacija koje nemaju ugrađenu podršku za AppleScript).

Pretpostavljam da sa "tell application xy to activate" postižeš to da njen menu postane aktivan u menu baru i da to zapravo treba čitati kao "tell application System events to tell application xy to activate"? Da? Ne?

"Activate" služi za prebacivanje aplikacije u prednji plan - u smislu da postane aktivna ako je prethodno fokus bio na nekoj drugoj aplikaciji. Također, brine se i za podizanje same aplikacije, što je u ovom slučaju uzaludan korak jer se moramo pobrinuti da "Preview" već bude dignut i u njega učitan odgovarajući dokument (što radimo preko shella jer ne možemo drugačije).

I da, može se čitati (i pisati) ovako kako si predložio, ali u tom slučaju si radimo "medvjeđu uslugu" jer kratimo dvije linije koda da bi potom svakoj koja slijedi eksplicitno morali reći kojem "objektu" se obraća. AppleScriptov "tell" je sličan poznatijem "with" (VB, JavaScripta...) - naredbe koje su unutar "tell" bloka odnose se na objekt specificiran kao parametar tella (reference object). Dakle, ako šaljemo samo jednu naredbu možemo koristiti sintaksu...

tell objekt_kojem_se_obracamo to napravi_nesto

...ali ako imamo vise od jedne naredbe onda je manje posla ako pišemo...

tell objekt kojem_se_obraćamo
  naredba1
  naredba2
...
end tell

Ono što ne kužim čemu služi je "tell process xy" pa onda "tell menu bar 1"?

Pretpostavljam da općenito bilo koja aplikacija može pokrenuti više procesa (kao više prozora ili...?) pa onda treba System Eventsu reći koji točno proces nas zanima? Da? Ali što onda još "menu bar 1"?

Dobro pretpostavljaš.

Svaka aplikacija može pokrenuti više procesa (najmanje 1), a prozori i menu barovi pripadaju (hijerarhijski) upravo tim procesima. "menu bar 1" je prvi (defaultni) menu bar - proces ih može imati više.

Odgovori Citiraj

Prva stranica PDFova

Vikalica™

Prijava

Prisutni jabučari

Novo na Jabučnjaku

Teme

Poruke

Članci

Oglasi

Komentari

Anketa

Koji Mac koristite?