display alert "Promjena u adresaru" message "Skripta će u svim unesenim kontaktima u Adresaru odabranu labelu broja telefona promijeniti u neku drugu, proizvoljnu."
-- postavljamo početne vrijednosti varijabli
set izlab to ""
set ulab to ""
-- korisnik mora zadati labelu broja telefona koju želi promijeniti, a ako unese prazno, mora ponoviti
repeat until izlab is not equal to ""
	display dialog "Unesi labelu koja se mijenja" default answer "home"
	-- dijalog vraća skup vrijednosi koji se sastoji od unesenog teksta i uklikanog gumba
	set izlab to text returned of result
end repeat
-- korisnik mora zadati labelu koju broj telefona ima nositi nakon promjene, a ako unese prazno, mora ponoviti
repeat until ulab is not equal to ""
	display dialog "Unesi labelu u koju se mijenja" default answer "work"
	set ulab to text returned of result
end repeat
-- pozivamo adresar
tell application "Address Book"
	-- ovo nam je samo kontrolni brojač
	set brojac to 0
	-- moramo pročešljati sve osobe u adresaru (ali grupe nas ne zanimaju)
	repeat with osoba in every person
		-- a onda za svaku osobu pročešljati sve telefonske brojeve
		repeat with broj in every phone of osoba
			-- ako je labela broja jednaka onoj koju tražimo
			if label of broj is equal to izlab then
				-- promijenit ćemo je u ono što treba biti
				set label of broj to ulab
				-- i povećati kontrolni brojač
				set brojac to (brojac + 1)
			end if
		end repeat
	end repeat
end tell
-- na kraju korisniku javljamo koliko je ukupno zapisa promijenjeno
display alert "Promjena u Adresaru" message "Ukupno promijenjeno " & brojac & " zapisa!"

tell application "Address Book"
    set popis to name of every person whose last name is missing value
    choose from list popis with prompt "Čiji broj tražiš?"
end tell

set popis to popis & "dodano ime"